buildscript {
    dependencies {
        constraints {
            classpath("org.apache.logging.log4j:log4j-core") {
                version {
                    strictly("[2.17, 3[")
                    prefer("2.17.0")
                }
                because("CVE-2021-44228, CVE-2021-45046, CVE-2021-45105: Log4j vulnerable to remote code execution and other critical security vulnerabilities")
            }
        }
    }
}

plugins {
    id("com.github.johnrengelman.shadow") version Libs.com_github_johnrengelman_shadow_gradle_plugin
    kotlin("jvm")
    application
}

group = "com.anthonycicchetti"
version = file("VERSION").readText().trim()

repositories {
    mavenCentral()
}

dependencies {
    constraints {
        implementation("org.apache.logging.log4j:log4j-core") {
            version {
                strictly("[2.17, 3[")
                prefer("2.17.0")
            }
            because("CVE-2021-44228, CVE-2021-45046, CVE-2021-45105: Log4j vulnerable to remote code execution and other critical security vulnerabilities")
        }
    }
    implementation(Kotlin.stdlib.jdk8)
    implementation(Libs.javalin)
    implementation(Libs.javalin_openapi)
    implementation(Libs.slf4j_simple)
    implementation(Libs.jackson_databind)
    implementation(Libs.jackson_module_kotlin)
    implementation(Libs.swagger_core)
    implementation(Libs.swagger_ui)
    implementation(Libs.slack_api_model_kotlin_extension)
    implementation(Libs.fuel)
    implementation(Libs.fuel_jackson)

    testImplementation(Libs.junit_jupiter)
}

application {
    mainClass.set("com.anthonycicchetti.slackbot.MainKt")
}

kotlin {
    jvmToolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

tasks.withType<Test> {
    useJUnitPlatform()
    testLogging {
        events("passed", "skipped", "failed")
    }
}