plugins {
    alias(libs.plugins.com.gradleup.shadow)
    alias(libs.plugins.org.jetbrains.kotlin.jvm)
    alias(libs.plugins.org.jetbrains.kotlin.plugin.serialization)
    application
    `jvm-test-suite`
}

group = "com.anthonycicchetti"
version = file("VERSION").readText().trim()

repositories {
    mavenCentral()
}

dependencies {
    constraints {
        implementation("org.apache.logging.log4j:log4j-core:_") {
            version {
                strictly("[2.17, 3[")
                prefer("2.17.0")
            }
            because("CVE-2021-44228, CVE-2021-45046, CVE-2021-45105: Log4j vulnerable to remote code execution and other critical security vulnerabilities")
        }
    }
    implementation(libs.javalin)
    implementation(libs.javalin.openapi)
    implementation(libs.slf4j.simple)
    implementation(libs.swagger.core)
    implementation(libs.swagger.ui)
    implementation(libs.slack.api.model.kotlin.extension)
    implementation(libs.ktor.client.core)
    implementation(libs.ktor.client.cio)
    implementation(KotlinX.serialization.json)

    testImplementation(libs.junit.jupiter)
}

application {
    mainClass.set("com.anthonycicchetti.slackbot.MainKt")
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

testing {
    suites {
        val test by getting(JvmTestSuite::class) {
            useJUnitJupiter()
        }
    }
}