From bd1567d573f98c96c258d906ef9ae574bf883e9b Mon Sep 17 00:00:00 2001
From: Eduardo Gurgel <edgurgel@gmail.com>
Date: Tue, 7 Jan 2014 21:01:10 -0300
Subject: [PATCH] Add '/redirect/:n'

---
 lib/httparrot.ex                  |  1 +
 lib/httparrot/get_handler.ex      |  2 +-
 lib/httparrot/redirect_handler.ex | 34 +++++++++++++++++++
 test/redirect_handler_test.exs    | 54 +++++++++++++++++++++++++++++++
 4 files changed, 90 insertions(+), 1 deletion(-)
 create mode 100644 lib/httparrot/redirect_handler.ex
 create mode 100644 test/redirect_handler_test.exs

diff --git a/lib/httparrot.ex b/lib/httparrot.ex
index b825cf8..4334e89 100644
--- a/lib/httparrot.ex
+++ b/lib/httparrot.ex
@@ -12,6 +12,7 @@ defmodule HTTParrot do
              {'/patch', HTTParrot.PHandler, []},
              {'/delete', HTTParrot.DeleteHandler, []},
              {'/status/:code', HTTParrot.StatusCodeHandler, []},
+             {'/redirect/:n', HTTParrot.RedirectHandler, []},
              {'/redirect-to', HTTParrot.RedirectToHandler, []},
              {'/cookies', HTTParrot.CookiesHandler, []},
              {'/cookies/set', HTTParrot.SetCookiesHandler, []},
diff --git a/lib/httparrot/get_handler.ex b/lib/httparrot/get_handler.ex
index 981009a..d327ad0 100644
--- a/lib/httparrot/get_handler.ex
+++ b/lib/httparrot/get_handler.ex
@@ -9,7 +9,7 @@ defmodule HTTParrot.GetHandler do
   end
 
   def allowed_methods(req, state) do
-    {["GET"], req, state}
+    {["GET", "HEAD", "OPTIONS"], req, state}
   end
 
   def content_types_provided(req, state) do
diff --git a/lib/httparrot/redirect_handler.ex b/lib/httparrot/redirect_handler.ex
new file mode 100644
index 0000000..8fac32a
--- /dev/null
+++ b/lib/httparrot/redirect_handler.ex
@@ -0,0 +1,34 @@
+defmodule HTTParrot.RedirectHandler do
+  @moduledoc """
+  Redirects to the foo URL.
+  """
+
+  def init(_transport, _req, _opts) do
+    {:upgrade, :protocol, :cowboy_rest}
+  end
+
+  def allowed_methods(req, state) do
+    {["GET", "HEAD", "OPTIONS"], req, state}
+  end
+
+  def malformed_request(req, state) do
+    {n, req} = :cowboy_req.binding(:n, req)
+    try do
+      n = n |> binary_to_integer |> max(1)
+      {false, req, n}
+    rescue
+      ArgumentError -> {true, req, state}
+    end
+  end
+
+  def resource_exists(req, state), do: {false, req, state}
+  def previously_existed(req, state), do: {true, req, state}
+
+  def moved_temporarily(req, n) do
+    {host_url, req} = :cowboy_req.host_url(req)
+    url = if n > 1, do: "/redirect/#{n-1}", else: "/get"
+    {{true, host_url <> url}, req, nil}
+  end
+
+  def terminate(_, _, _), do: :ok
+end
diff --git a/test/redirect_handler_test.exs b/test/redirect_handler_test.exs
new file mode 100644
index 0000000..634958a
--- /dev/null
+++ b/test/redirect_handler_test.exs
@@ -0,0 +1,54 @@
+defmodule HTTParrot.RedirectHandlerTest do
+  use ExUnit.Case
+  import :meck
+  import HTTParrot.RedirectHandler
+
+  setup do
+    new :cowboy_req
+  end
+
+  teardown do
+    unload :cowboy_req
+  end
+
+  test "malformed_request returns false if it's not an integer" do
+    expect(:cowboy_req, :binding, [{[:n, :req1], {"a2B=", :req2}}])
+
+    assert malformed_request(:req1, :state) == {true, :req2, :state}
+
+    assert validate :cowboy_req
+  end
+
+  test "malformed_request returns false if it's an integer" do
+    expect(:cowboy_req, :binding, [{[:n, :req1], {"2", :req2}}])
+
+    assert malformed_request(:req1, :state) == {false, :req2, 2}
+
+    assert validate :cowboy_req
+  end
+
+  test "malformed_request returns 1 if 'n' is less than 1" do
+    expect(:cowboy_req, :binding, [{[:n, :req1], {"0", :req2}}])
+
+    assert malformed_request(:req1, :state) == {false, :req2, 1}
+
+    assert validate :cowboy_req
+  end
+
+  test "moved_temporarily returns 'redirect/n-1' if n > 1" do
+    expect(:cowboy_req, :host_url, 1, {"host", :req2})
+
+    assert moved_temporarily(:req1, 4) == {{true, "host/redirect/3"}, :req2, nil}
+
+    assert validate :cowboy_req
+  end
+
+  test "moved_temporarily returns '/get' if n = 1" do
+    expect(:cowboy_req, :host_url, 1, {"host", :req2})
+
+    assert moved_temporarily(:req1, 1) == {{true, "host/get"}, :req2, nil}
+
+    assert validate :cowboy_req
+  end
+
+end