dotfiles/zsh/zshrc

HISTFILE=~/.histfile
HISTSIZE=10000
SAVEHIST=10000
setopt extendedglob nomatch notify histignorespace histignorealldups histnofunctions histnostore histverify incappendhistory autopushd pushdignoredups
unsetopt autocd beep

if [[ -f /nix/var/nix/profiles/default/etc/profile.d/nix-daemon.sh ]];
then
    . /nix/var/nix/profiles/default/etc/profile.d/nix-daemon.sh
fi


bindkey -v
# allow ctrl-a and ctrl-e to move to beginning/end of line
bindkey '^a' beginning-of-line
bindkey '^e' end-of-line
export RPROMPT=' ' # Fixes a side-effect of the vi-mode oh-my-zsh plugin

export KEYTIMEOUT=1

typeset -U path
typeset -U fpath

if [[ $(uname) == 'Darwin' ]]; then
    if [[ $(arch) == 'arm64' ]]; then
        path+=('/opt/homebrew/bin')
    else
        path+=('/usr/local/bin')
    fi
fi

hash -d -- -dotfiles=~/.dotfiles
hash -d -- -src=~/src
hash -d -- -doom=~/.doom-emacs

fpath=(~/bin ~/.zshcompletions $fpath)
zstyle :compinstall filename '/home/anthonys/.zshrc'
zstyle ":completion:*" complete _complete _ignored _approximate _expand
zstyle ":completion:*" glob 1
zstyle ":completion:*" insert-unambiguous true
zstyle ':completion:*' menu select
zstyle ':completion:*' rehash true
zstyle ':completion:*' matcher-list 'r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]}' 'l:|=* r:|=*'
zstyle ":completion:*" substitute 1

autoload -Uz up-line-or-beginning-search down-line-or-beginning-search zmv colors
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search

[[ -n "$key[Up]"   ]] && bindkey -- "$key[Up]"   up-line-or-beginning-search
[[ -n "$key[Down]" ]] && bindkey -- "$key[Down]" down-line-or-beginning-search

_command-exists() {
    [[ -x "$(command -v $1)" ]] && return 0 || return 1
}

export COMPLETION_WAITING_DOTS="true"
export VISUAL='nvim'
export EDITOR='nvim'
path=("$HOME/bin" "$HOME/go/bin" $path)

local ZSH_PLUGIN_DIR="$HOME/.zsh_plugins"
zstyle ':znap:*' repos-dir "${ZSH_PLUGIN_DIR}"
zstyle ':znap:*' auto-compile no
zstyle ':znap:*:*' git-maintenance off
autoload -Uz add-zle-hook-widget

local ZSH_PLUGIN_DIR="$HOME/.zsh_plugins"
if [[ ! -d "${ZSH_PLUGIN_DIR}/zsh-snap" ]]; then
    mkdir -p ~/.zsh_plugins
    cd ~/.zsh_plugins
    git clone https://github.com/marlonrichert/zsh-snap.git
fi
source "${ZSH_PLUGIN_DIR}/zsh-snap/znap.zsh" && export ZNAP_USED=1

local -a paths
for line in "${(@f)"$(<~/.zsh_plugins.txt)"}"
{
    if [[ ! -d "${ZSH_PLUGIN_DIR}/$(basename $line)" ]]; then
        paths=($paths $line)
    fi
}

if [[ ! ${#paths[@]} -eq 0 ]]; then
    echo "Paths not empty:  $paths"
    znap clone ${^paths}
fi

if [[ ( $ZNAP_USED = 1 ) ]]; then
    znap source oh-my-zsh lib/{git,completion}
    znap source oh-my-zsh plugins/colored-man-pages
    fpath=($fpath ~[oh-my-zsh]/plugins/{pass,ripgrep,cargo,docker,docker-compose,rsync,fd})
    znap source fast-syntax-highlighting
    fpath=($fpath ~[zsh-completions]/src)
    znap source zsh-vimode-visual
fi

if [[ -d ~/.cargo/bin ]]; then
    path=($path $HOME/.cargo/bin)
fi

if (_command-exists starship); then
    znap eval starship 'starship init zsh --print-full-init'
    znap prompt 
else 
    if [[ ( $ZNAP_USED = 1 ) ]]; then
        autoload -Uz promptinit
        promptinit
        znap clone https://github.com/denysdovhan/spaceship-prompt
        znap prompt spaceship-prompt
    fi
fi

autoload -Uz compinit
compinit

znap source oh-my-zsh plugins/{gitignore,git,helm,mvn,gradle}

if [[ $(uname -s) =~ 'Linux' ]]; then
    alias cp="cp --reflink=auto"
fi

function dt() {
    local session_name
    session_name=${1:-DefaultSession}

    if [[ "${SESSION_MANAGER}" == "tmux" ]]; then
        tmux -u -2 new-session -A -s $session_name
    else 
        zellij attach -c $session_name
    fi
} 

function send-to-pane() {
    tmux pipe-pane -I -t $1 "$2 | head -n 1"
}

function _send_to_pane {
    reply=($(tmux display-panes -b ''))
}
compctl -K _send_to_pane send-to-pane

function root() {
    if [[ -n $(git rev-parse --show-toplevel) ]]
    then
        cd "$(git rev-parse --show-toplevel)"
    fi
}

if [[ -d $HOME/.anyenv ]]; then
    path+=($HOME/.anyenv/bin)
    if [[ ( $ZNAP_USED = 1 ) ]]; then
        znap eval anyenv-init ${${:-=anyenv}:A}' init -'
    else
        eval "$(anyenv init -)"
    fi
fi


if (_command-exists direnv); then
    eval "$(direnv hook zsh)"
fi

##THIS MUST BE AT THE END OF THE FILE FOR SDKMAN TO WORK!!!
export SDKMAN_DIR="$HOME/.sdkman"
[[ -s "$HOME/.sdkman/bin/sdkman-init.sh" ]] && znap eval sdkman-init "cat $HOME/.sdkman/bin/sdkman-init.sh   # $SDKMAN_VERSION"

if [[ -a $HOME/.zshsrc ]]; then
	source $HOME/.zshsrc 
else 
	printf "No zshsrc\nOne has been created\n"
	touch $HOME/.zshsrc
fi

LS_PICKER="eza"
CTRL_R_PICKER="atuin"
alias exa="eza -l --git"
alias eza="eza -l --git"

for funcfile in $HOME/.zsh.d/* ; do
    source "${funcfile}"
done

if [[ "${CTRL_R_PICKER}" == "mcfly" ]]; then
    znap eval mcfly 'mcfly init zsh'
    export MCFLY_KEY_SCHEME=vim
    export MCFLY_FUZZY=true
    export MCFLY_RESULTS=50
    export MCFLY_USED=1
fi

if [[ "${CTRL_R_PICKER}" == "atuin" ]]; then
    znap eval atuin 'atuin init zsh'
fi